Population trends of female Elephant Seals breeding on the Courbet Peninsula, îles Kerguelen

Abstract

Southern Elephant Seals are upper marine predators of the Southern Ocean. As such, their population dynamics and fluctuations reflect environment conditions. Their worldwide populations crashed during the second half of the twentieth century for reasons not yet completely elucidated. Here, we studied the largest population of Southern Elephant Seals within the South Indian Ocean that are breeding on îles Kerguelen. In a previous analysis, Guinet et al. in Antarct Sci 11:193–197, 1999) suggested that the decline on îles Kerguelen might be over, as observed elsewhere. Using 10 years of additional data, we updated this analysis using state-of-the-art statistical methods to account for most uncertainties associated with count data. We showed that the population of female Southern Elephant Seals breeding on îles Kerguelen has been stable over the past 20 years. Despite concomitant global changes within the Southern Ocean, we did not find any evidence of a phenological shift in peak haul-out date of breeding females between the 1970s and the 2000s.

Appendix

WinBUGS code to fit Rothery and McCann (1987)’s model

## Data

# N : number of data points

# N.site : number of surveyed rookeries

# N.who : number of different field workers

# t[] : census date (0 = 15th October)

# n[] : number of counted females

# site[] : dummy code for each surveyed rookery

# who[] : dummy code for who made the census

# S : mean length a female stays ashore (in days)

## Parameters of Inferential Interest

# sd : residual error

# nu : number of degrees of freedom of the Student distribution

# beta : marginal means

# Nmax : maximum number of females present on each site

# peak.return : date of peak return of females on each site

# peak.haulout : date of peak presence of females on each site

# sd.b : site variances

# cor.b : correlation between Nmax, peak.return and synchrony

# sd.observer : observer error

##

model{

# Likelihood, Student distribution for residual error

for (i in 1 : N) {

n[i] ~ dt(mu[i],tau,nu)

mu[i] < - Nmax[Site[i]]*p[i] + observer[who[i]]

p[i] < - phi(Arrival[i]) - phi(Departure[i])

Arrival[i] < - (t[i]-peak.return[Site[i]])/synchrony[Site[i]]

Departure[i] < - (t[i]-S.cut-peak.return[Site[i]])/synchrony[Site[i]]

}

# Priors

tau < - pow(sd,-2); sd ~ dunif(0,100); nu ~ dunif(2,50);

for (i in 1 : N.site) {peak.haulout[i] < - peak.return[i] + S.cut/2}

## the cut() function is to prevent the data from feedbacking on S

S.cut < - cut(S); S ~ dnorm(28,0.20)

# Half-Cauchy (weakly informative) prior for beta[1] (Nmax > 0)

beta[1] < - abs(raw.beta[1]); prior.scale[1] < - 1000

raw.beta[1] ~ dnorm(0,tau.beta[1]);

tau.beta[1] < - pow(prior.scale[1],-2)*eta.beta[1];

# Cauchy Prior (weakly informative) for beta[2] (peak.return)

beta[2] < - raw.beta[2]; prior.scale[2] < - 10

raw.beta[2] ~ dnorm(0,tau.beta[2]);

tau.beta[2] < - pow(prior.scale[2],-2)*eta.beta[2];

# Half-Cauchy (weakly informative) for beta[3] (synchrony > 0)

beta[3] < - abs(raw.beta[3]); prior.scale[3] < - 10

raw.beta[3] ~ dnorm(0,tau.beta[3]);

tau.beta[3] < - pow(prior.scale[3],-2)*eta.beta[3];

# Inverse-Wishart prior for site variances

for (i in 1 : (N.site + 1)) {

Nmax[i] < - B[i,1]; B.hat[i,1] < - beta[1]

peak.return[i] < - B[i,2]; B.hat[i,2] < - beta[2]

synchrony[i] < - B[i,3]; B.hat[i,3] < - beta[3]

B[i,1:3] ~ dmnorm(B.hat[i,],tau.B[,])

}

tau.B[1:3,1:3] ~ dwish(W[,],3); SD[1:3,1:3] < - inverse(tau.B[,]);

W[1,1] < - 150; W[1,2] < - 0; W[1,3] < - 0;

W[2,1] < - 0; W[2,2] < - 4; W[2,3] < - 0;

W[3,1] < - 0; W[3,2] < - 0; W[3,3] < - 2;

for (j in 1 : 3) {

sd.b[j] < - sqrt(SD[j,j]);

eta.beta[j] ~ dgamma(0.5,0.5)

}

cor_b[1] < - SD[1,2]/sqrt(SD[1,1]*SD[2,2])

cor_b[2] < - SD[1,3]/sqrt(SD[1,1]*SD[3,3])

cor_b[3] < - SD[2,3]/sqrt(SD[2,2]*SD[3,3])

# Half-Cauchy Priors for fieldworker variance

for (i in 1:N.who) {

observer[i] < - x*U[i];

U[i] ~ dnorm(0,tau.U)

}

x ~ dnorm(0,tau.x);

tau.x < - pow(prior.scale.who,-2);

tau.U ~ dgamma(0.5,0.5)

sd.observer < - abs(x)/sqrt(tau.U);

prior.scale.who < - 10

} # end of model