Nonlinear Random-Effects Mixture Models for Repeated Measures

Abstract

A mixture model for repeated measures based on nonlinear functions with random effects is reviewed. The model can include individual schedules of measurement, data missing at random, nonlinear functions of the random effects, of covariates and of residuals. Individual group membership probabilities and individual random effects are obtained as empirical Bayes predictions. Although this is a complicated model that combines a mixture of populations, nonlinear regression, and hierarchical models, it is straightforward to estimate by maximum likelihood using SAS PROC NLMIXED. Many different models can be studied with this procedure. The model is more general than those that can be estimated with most special purpose computer programs currently available because the response function is essentially any form of nonlinear regression. Examples and sample code are included to illustrate the method.

Appendices

Appendix A

In this section we present code to fit model (12) with a mixture of random effects distributions given in (13). The code is divided into five sections. In Section 1 model options are specified, starting values for model parameters are given, and terms (both constants and functions of model parameters) that will be used throughout the model are defined. The final line of this section also defines the distribution of the random effects to be standard normal. This is simply a computing strategy, and the distribution of the random effects will be rescaled in later sections.

Terms that are needed to define the likelihood function are computed in Sections 2 and 3. In particular, terms that need to be compiled over time for each individual are defined in Section 2. Using the notation from Equations (9) and (10), terms that are common to both classes and terms that are unique to each are defined in Section 3.

The log-likelihood function is then defined in Section 4. Following (8), the likelihood function involves 3 distributions: (1) the conditional distribution of the data given random effects and group, m _g (y _i |u,g), (2) the distribution of the random effects, h _g (u|g), and (3) a standard normal distribution of the random effects. Lpart1 involves the pieces of the log-likelihood function that are common to both classes for this particular model. The pieces that are unique to the latent classes are given in Lpart2. Because this piece involves taking the log of a sum, we use the identity ln(a+b)=ln(e ^{ln(a)−ln(b)}+1)+ln(b), where ln(a) defines the terms from the overall log-likelihood function that are unique to the first class and ln(b) defines the terms that are unique to the second class. Finally, Lpart3 defines the standard normal distribution of the random effects. These terms are all then combined to create the overall log-likelihood function which is labeled Li. Even though all of the data is included in Li, NLMIXED still requires that a variable be listed on the left side of the tilde in the model statement. Therefore, the variable “dum” simply acts as a placeholder.

*Section 1;

proc nlmixed data=learning qpoints=30;

  array y{*} y0-y35;

  parms int=10.5 g1_max=27.6 g2_max=42.6 rate=.05 ph11=5.1

  ph22=21.7 ve=4.5 p1=.3;

    ni = 36;

    nb = 2;

    pi = constant("pi");

    p2 = 1-p1;

  random u0 u1~ normal([0,0],[1,0,1]) subject=id;

*Section 2;

  s=0;

  do j = 1 to ni;

    t = j-1;

    f = u1 - (u1-u0)*exp(-rate*t);

    s = s + (y[j]-f)**2;

  end;

*Section 3;

  *overall;

    Q = s/ve;

    dg = ph11*ph22; *determinant of phi;

    dig = ve**ni; *determinant of lambda;

  *population 1;

    v11 = u0-int;

    v21 = u1-g1_max;

    qi1 = ((v11**2)*ph22 + (v21**2)*ph11)/dg;

  *population 2;

    v12 = u0-int;

    v22 = u1-g2_max;

    qi2 = ((v12**2)*ph22 + (v22**2)*ph11)/dg;

*Section 4;

  Lpart1 = -.5*((ni+nb)*log(2*pi) + log(dig) + log(dg) + Q);

    lna = log(p1) -.5*(qi1);

    lnb = log(p2) -.5*(qi2);

  Lpart2 = log(exp(lna-lnb)+1)+lnb;

  Lpart3 = (-nb/2)*log(2*pi) -.5*(u0**2 + u1**2);

  Li = Lpart1 + Lpart2 - Lpart3;

  dum=1;

  model dum~general(Li);

*Section 5;

  prob1 = (p1*exp(-.5*qi1))/((p1*exp(-.5*qi1))+(p2*exp(-.5*qi2)));

  predict u0 out=u0 (keep=id pred rename=(pred=rand_u0));

  predict u1 out=u1 (keep=id pred rename=(pred=rand_u1));

  predict prob1 out=prob1 (keep=id pred rename=(pred=group_memb));

run;

Appendix B

This example fits model (14) with (13) as the covariance matrix of the conditional distribution of u _i |g. The code is formatted similarly to that found in Appendix A. There are two differences to point out. First, parameters that vary widely in terms of scale can sometimes hinder convergence in the estimation procedure; therefore, it is often useful to rescale some of the parameters. This is done here in Section 1. Second, in Section 2 a small constant is added to the denominator of the f term so as to avoid diving by zero in the initial iteration when both t and u1 are equal to zero.

*Section 1;

proc nlmixed data=learning qpoints=30;

  array y{*} y0-y35;

  parms int=9.8 g1_max=51 g2_max=29 half_max=14 s11=14 s22=9

  se=100 p1z=5.1;

     p1 = p1z/10; ph11 = s11*s11; ph22 = s22*s22; ve = se*se;

     ni = 36; nb = 2; pi = constant("pi");

     p2 = 1-p1;

  random u0 u1~ normal([0,0],[1,0,1]) subject=id;

*Section 2;

   s=0;

   do j = 1 to ni;

      t = j-1;

      f = int + (u0*t)/(u1+t+.00001);

      s = s + (y[j]-f)**2;

   end;

*Section 3;

   *overall;

      Q = s/ve;

      dg = ph11*ph22; *determinant of phi;

      dig = ve**ni; *determinant of lambda;

   *population 1;

      v11 = u0-g1_max;

      v21 = u1-half_max;

      qi1 = ((v11**2)*ph22 + (v21**2)*ph11)/dg;

   *population 2;

      v12 = u0-g2_max;

      v22 = u1-half_max;

      qi2 = ((v12**2)*ph22 + (v22**2)*ph11)/dg;

*Section 4;

   Lpart1 = -.5*((ni+nb)*log(2*pi) + log(dig) + log(dg) + Q);

      lna = log(p1) -.5*(qi1);

      lnb = log(p2) -.5*(qi2);

   Lpart2 = log(exp(lna-lnb)+1)+lnb;

   Lpart3 = (-nb/2)*log(2*pi) -.5*(u0**2 + u1**2);

   Li = Lpart1 + Lpart2 - Lpart3;

   dum=1;

   model dum~general(Li);

*Section 5;

   prob1 = (p1*exp(-.5*qi1))/((p1*exp(-.5*qi1))+(p2*exp(-.5*qi2)));

   estimate 'ph11' ph11; estimate 'ph22' ph22; estimate 'p1' p1;

   estimate 've' ve;

   predict u0 out=u0 (keep=id pred rename=(pred=u0));

   predict u1 out=u1 (keep=id pred rename=(pred=u1));

   predict prob1 out=prob1 (keep=id pred rename=(pred=group_memb));

run;

Appendix C

This example uses (15) for the response function, (16) for the variance of the random intercept, and (17) for the variance function of the residuals. The additional code in the following example can be attributed to the fact that the quadratic model has fixed effects that differ between groups and a more complicated error structure than the previous two models. All of the necessary adjustments for these differences are made in Section 2. The differences in fixed effects between groups are accounted for by computing f _ig (a _i ,b _i ,κ _g ,τ) separately for each group (f_g1 and f_g2). The linear change in the error variance over time is specified in the ve term. The determinant of Λ _i is calculated in the term “dig” and the $\mathbf{e}'_{ig}\boldsymbol{\Lambda}_{ig}^{ - 1}\mathbf{e}_{ig}$ term from the conditional distribution of the data given the random effects is defined by “Qi1” for group 1 and by “Qi2” for group 2.

*Section 1;

proc nlmixed data=learning qpoints=40;

   array y{*} y0-y35;

   parms int=11.2 g1_slope=.94 g2_slope=1.16 quad=-.01

   ve_int=5.8 ve_slp=-.08

         ph11=11.2 p1=.4;

     ni = 36; nb = 1;

     pi = constant(''pi'');

     p2 = 1-p1;

   random u0 ~ normal([0],[1]) subject=id;

*Section 2;

   Qi1=0; Qi2=0; dig=1;

      do j = 1 to ni;

         t = j-1;

         f_g1 = u0 + g1_slope*t + quad*t*t;

         f_g2 = u0 + g2_slope*t + quad*t*t;

         s_g1 = (y[j]-f_g1)**2;

         s_g2 = (y[j]-f_g2)**2;

         ve = ve_int + ve_slp*t;

         dig = dig * ve; *determinant of lambda;

         Qi1 = Qi1 + (s_g1 / ve);

         Qi2 = Qi2 + (s_g2 / ve);

      end;

*Section 3;

   *overall;

      dg = ph11; *determinant of phi;

      v11 = u0-int;

      num = v11**2;

      qi = num/dg;

*Section 4;

   Lpart1 = -.5*((ni+nb)*log(2*pi) + log(dig) + log(dg) + qi);

        lna = log(p1) -.5*(Qi1);

        lnb = log(p2) -.5*(Qi2);

   Lpart2 = log(exp(lna-lnb)+1)+lnb;

   Lpart3 = (-nb/2)*log(2*pi) -.5*(u0**2);

   Li = Lpart1 + Lpart2 - Lpart3;

   dum=1;

   model dum~general(Li);

*Section 5;

   predict u0 out=u0 (keep=id pred rename=(pred=u0));

run;