Analog Integrated Circuits and Signal Processing

, Volume 66, Issue 1, pp 129–137 | Cite as

PSPICE modeling of meminductor

Open Access
Mixed Signal Letter


PSPICE models of current- and flux-controlled meminductor are described. The models consist of two parts, one of which represents the state-space description of the memory effect of the device, and the other part is an inductor whose inductance depends on the system state. The basic fingerprints of the meminductor, i.e. the flux–current pinched hysteresis loops, the unambiguous constitutive relation between the time integral of flux and electric charge, and identical zero-crossing points of flux and current waveforms are demonstrated on the example of current-controlled meminductor.


Meminductor Model SPICE 

1 Introduction

The discovery of solid-state memristor in Hewlett-Packard (HP) labs, reported in Nature in May 2008 [1], initiated a growing interest in computer modeling and simulation of memristor [2, 3, 4, 5, 6, 7, 8, 9], the fourth fundamental passive element, theoretically predicted by Chua in 1971 [10]. The reason consists in the fact that the above device is not currently available as off-the-shelf circuit. Then its model, particularly when implemented in current programs for circuit simulation such as SPICE, can serve as an important tool in computer experiments with such devices.

In addition to the memristor, other hypothetical “mem-devices” have come into consideration within the last year, namely the memcapacitor and the meminductor [11, 12, 13, 14]. As noted in [15], “…combined with the already known memristor, such elements open up new and unexplored functionalities in electronics…”.

In order to enable simulation experiments with the above mem-elements, the existing PSPICE models of memristor should be complemented with similar models of memcapacitor and meminductor. The first step was performed in [16], where a general methodology for PSPICE modeling of mem-devices was introduced. The very first PSPICE model of the memcapacitor was published in [17]. To the best of our knowledge, no similar PSPICE model of the meminductor has been hitherto reported in the literature. Thereby, this Letter introduces foolproof models of current- and flux-controlled meminductors.

2 General models of current- and flux-controlled meminductors for PSPICE

According to [18], a network element can be defined axiomatically by its constitutive relation (CR), which does not depend on the element interaction with the surrounding networks. For the meminductor, the CR is the relation [16]
$$ f(\rho ,q) = 0, $$
where ρ is the time-domain integral of magnetic flux φ (TIF) of the meminductor, and q is the electric charge, i.e. the time integral of electric current i (TIC):
$$ \rho (t) = \int\limits_{ - \infty }^{t} {\varphi (\alpha )d\alpha } ,\quad q(t) = \int\limits_{ - \infty }^{t} {i(\alpha )d\alpha } . $$
If the CR (1) can be transformed such that it depicts the TIF as a single-valued function \( \hat{\rho } \) of the charge, namely
$$ \rho = \hat{\rho }(q), $$
then we talk about a current-controlled [12, 16] or a charge-controlled meminductor. In terms of meminductor flux and current, CR (3) can be rewritten in the form
$$ \varphi = L_{M} (q)i, $$
$$ L_{M} (q) = {\frac{{d\hat{\rho }(q)}}{dq}}\left| {\mathop {}\limits_{Q} } \right. $$
is the small-signal meminductance defined at the operating point Q [18].
Similarly, if CR (1) can depict the charge q as a single-valued function \( \hat{q} \) of the TIF,
$$ q = \hat{q}(\rho ), $$
then (6) defines a flux-controlled [12, 16] or TIF-controlled meminductor. CR (6) can be transformed into the form
$$ i = \Uplambda_{M} (\rho )\varphi , $$
$$ \Uplambda_{M} (\rho ) = {\frac{{d\hat{q}(\rho )}}{d\rho }}\left| {\mathop {}\limits_{Q} } \right. $$
is the small-signal inverse meminductance defined at the operating point Q.

It is shown on the example of HP memristor [1] that there is a significant difference between the behavior of the ideal hypothetical device (memristor) and its physical implementation. Since the key parameter of the device, resistance in the case of memristor, can be changed only within bounds that are given by the physical limitations of a concrete implementation, the HP memristor must be modeled as a more general memristive system [19]. Analogously, it is shown in [12, 16] that the memcapacitor and the meminductor are special cases of more general memcapacitive and meminductive systems. In order to model properly the meminductor also in its limit states, it should be regarded as a current- or flux-controlled meminductive system (CCMLS or FCMLS), respectively.

The CCMLS for modeling the current-controlled meminductor can be defined by the following algebraic port equation (PE) and first-order differential state equation (SE):
$$ {\text{PE:}}\,\varphi = L_{M} (x,i,t)i, $$
$$ {\text{SE:}} \, \dot{x} = \frac{d}{dt}x = f_{i} (x,i,t). $$
In general, LM( ) and fi( ) are nonlinear functions, which depend on the concrete physical implementation of the current-controlled meminductive system or meminductor. The suffix i denotes the current-controlled system.
Analogously, the FCMLS for modeling the flux-controlled meminductor can be defined as follows:
$$ {\text{PE:}}\,i = \Uplambda_{M} (x,\varphi ,t)\varphi , $$
$$ {\text{SE:}}\,\dot{x} = \frac{d}{dt}x = f_{\varphi} (x,\varphi,t), $$
where ΛM( ) and fφ( ) are nonlinear functions. The suffix φ denotes the flux-controlled system.

The functions fi( ) and fφ( ) should also model the so-called boundary effects, which cause the decrease of the speed of state variable to zero if the device state approaches its physical limits [20]. Details will be given in the following section.

Equations 912 can serve as a starting point for constructing PSPICE models of current- and flux-controlled meminductors operating on the basis of various physical principles. The basic schematics of such modeling are given in Fig. 1(a) and (b), together with the schematic symbol of the meminductor. The symbol should be used in accordance with [12]: when a positive voltage is applied to the upper terminal with respect to the terminal denoted by the black thick line, the meminductance is increased.
Fig. 1

Schematic symbol of the meminductor and block diagrams of SPICE modeling of a current-controlled, b flux-controlled meminductor

Port equations (9) and (11) are modeled by inductors with inductances controlled through the blocks LM( ) and ΛM( ). Input signals of these blocks are the system state x and the meminductor current (Fig. 1a) or flux (Fig. 1b). The flux is computed as a time-domain integral of meminductor voltage (see the block Intφ in Fig. 1b). Differential state equations (10) and (12) are modeled by the integrator Intx and the nonlinear blocks fi( ) and fφ( ), respectively.

The varying inductors in Fig. 1 can be modeled in PSPICE as follows. The general equation of the inductor with varying inductance LM or with varying inverse inductance ΛM = 1/LM
$$ \varphi (t) = \varphi (0) + \int\limits_{0}^{t} {v(\xi )d\xi } ,\;{\text{or}}\;L_{M} (t)i(t) = L_{M} (0)i(0) + \int\limits_{0}^{t} {v(\xi )d\xi } , $$
where φ(0) and i(0) are the initial flux and current at time 0, can be rewritten in the form
$$ i(t) = \Uplambda_{M} (t)[L_{M} (0)i(0) + \int\limits_{0}^{t} {v(\xi )d\xi } ]. $$
This equation can be modeled in PSPICE via a controlled current source. Note that the right-side integral is a flux, which must be computed. The mathematical formula of the inverse meminductance will depend on the concrete physical implementation of the meminductor.

3 Example of SPICE modeling of meminductor

Figure 2 shows a simple electro-mechanical model of meminductor. The coil has one fixed (on the left side) and one sliding terminal, which can be moved, depending on the circuit quantities described below, within limits defined by distances lmin and lmax from the fixed terminal. The slider positions lmin and lmax determine the limiting values of the coil inductances Lmin and Lmax. Let us define the dimensionless state variable x
$$ x = {\frac{{l - l_{\min } }}{{l_{\max } - l_{\min } }}}\; \in (0,1). $$
The coil inductance L is, roughly speaking, proportional to the square of the number of turns N:
$$ L \approx N^{2} /R_{M} , $$
where RM is the magnetic resistance of the magnetic part of the coil.
Fig. 2

Electro-mechanical model of the meminductor

Then the inductance LM of the meminductor in Fig. 2 depends on the state variable x approximately as follows:
$$ L(t) \approx \left[ {\sqrt {L_{\min } } + x(t)\left( {\sqrt {L_{\max } } - \sqrt {L_{\min } } } \right)} \right]^{2} $$
Consider the current-controlled meminductor. According to Eq. 10, the time derivative of the state variable, i.e. the speed of the motion of the normalized distance x of the coil slider from the fixed terminal in Fig. 2, must depend on the inductor current. Analogously to the charge-controlled HP memristor in [3] and memcapacitor in [17], consider state equation (10) of the current-controlled meminductor in the form
$$ \dot{x} = k \cdot i(t) \cdot window(x) $$
The rate of the change of the slider position is directly proportional to the meminductor current and to the mobility factor k. The purpose of the nonlinear function window(x) is to model the rate decrease to zero when the slider approaches the limit positions lmin and lmax. As known from papers on HP memristor, the modeling of such boundary effects can be accomplished by several types of window functions, which provide a transition to zero values such as the rectangular [12, 21], Joglekar [20], or Biolek [3] window, denoted by R, J, and B subscripts in the formulae below:
$$ window_{R} (x) = stp(x) - stp(x - 1),\;window_{J} (x) = 1 - (2x - 1)^{2p} ,\;window_{B} (x) = 1 - (x - stp( - xd))^{2p} $$
Here stp(x) is a step function, i.e. stp(x) = 1 when x ≥ 0, stp(x) = 0 when x < 0, p is a positive integer, and xd is a quantity which evaluates the direction of the change of the state variable, i.e. xd > 0 when x increases, and xd ≤ 0 when x decreases or is constant.
Figure 3(a) shows that if the control parameter p increases, the Joglekar window converges to the rectangular window. The basic problem of this window consists in the fact that when the state variable of the device is in its terminal value 0 or 1, no external stimulus can change this state because the time derivative of the state variable in (17) is zero, independently of the terminal signals. Such a discrepancy between the behavior of the model and the requirements for the operation of a real circuit element is resolved by the Biolek window, which reflects the fact that the speeds of receding from and approaching the limit positions of the slider are different. An illustration of how this window works is given in Fig. 3(b) for the control parameter p = 2. Details can be found in [3, 9]. As a conclusion, the more sophisticated Biolek window models well the device behavior also near its boundary states, but numerical problems in transient analysis due to the discontinuities at boundary points can appear more frequently than in the case of the Joglekar window. The Joglekar window can be advantageously used for cases when the mem-element operates far enough from its boundary states. Note that when applying the Biolek window, constitutive relation (1) will now depend on the way the meminductor interacts with the surrounding networks. However, it is only a consequence of the fact that the device in Fig. 2 is not an ideal meminductor but a more general meminductive system.
Fig. 3

Window functions according to Joglekar (a) and Biolek (b), the latter for p = 2 [3]

The SPICE subcircuit, modeling the meminductor from Fig. 2, is shown in Table 1 together with the self-explanatory notes.
Table 1

PSPICE subcircuit of the meminductor from Fig. 2




.SUBCKT memL Plus Minus PARAMS:


+ Lmin=1mH Lmax=20mH Linit=5mH k=10 p=10 IC=0


* Input port *


Vsense Plus + 0 V; sensing of the meminductor current


Gml + Minus value={(V(flux)+IC*Linit)/LM(V(x))}; see Eq. 13


*Flux computation via time-domain integration of meminductor voltage*


Gflux 0 flux value={V(plus,minus)}


Cflux flux 0 1


Rflux flux 0 1G


*State-space equation (17). Intx from Fig. 1 is formed by Cx and Gx*


.param xinit {(sqrt(Linit)−sqrt(Lmin))/(sqrt(Lmax)−sqrt(Lmin))}; results from Eq. 16


Gx 0 x value={I(Vsense)*k*windowJ(V(x),p)}; version for Joglekar window, see Eq. 17


;Gx 0 x value={I(Vsense)*k*windowB(V(x),I(Vsense),p)}; version for Biolek window, see Eq. 17


Cx x 0 1 IC={xinit}


Rx x 0 1G


*Functions for defining meminductance and boundary effects


.func LM(x)={(sqrt(Lmin)+x*(sqrt(Lmax)−sqrt(Lmin)))^2}; see Eq. 16


.func windowJ(x,p)={1−(2*x−1)^(2*p)}; Joglekar window, see Eq. 18


.func windowB(x,xd,p)={1−(x−stp(−xd))^(2*p)}; Biolek window, see Eq. 18


*Computing charge and time-domain integral of flux (TIF)


Gcharge 0 0 value={SDT(I(Vsense))}


Gintflux 0 0 value={SDT(V(flux))}


.ENDS memL

The Vsense voltage source, defined on line 4, serves to sense the meminductor current. The value of this current is needed for modeling the state equation on line 12 or 13 as well as for computing the charge on line 21. The code on line 12 can be replaced by the text on line 13 when the Biolek window is used instead of the Joglekar window. The integrator Intx in Fig. 1(a) is accomplished by a capacitor Cx with 1F capacitance, charged from a current source Gx, which provides current according to Eq. 17. A shunting resistor Rx is needed in order to provide the DC path to the ground. The initial state xinit of the device is derived from the initial value of inductance Linit, see line 11. The flux computation as a time-domain integral of meminductor voltage is done similarly on lines 7–9.

In order to easily visualize constitutive relation (1), the charge and TIF computations are performed on lines 21 and 22. For simplicity, the time-domain integrations are provided via a PSPICE function SDT, not by means of the current source and capacitor. To save model nodes, the computation is arranged via current sources with each terminal grounded. The values of these currents are equal to the charge and TIF and thus they can be used for the visualization of the CR. Note that the SDT function was not utilized in the above-mentioned models of integrators. The main reason for not using the SDT function is that the precision of these integrators can then be adjusted via a proper selection of the component parameters.

The results of PSPICE transient analysis are shown in Fig. 4. The analysis was performed for the meminductor with default parameters given in Table 1 and the Joglekar window, excited by a harmonic current source with an amplitude of 100 mA and a frequency of 1 Hz, with an auxiliary 1 GΩ shunting resistor. The results shown in Fig. 4 clearly demonstrate three basic fingerprints of the meminductor [11]: Unambiguous constitutive relation (1) (Fig. 4a), the pinched hysteretic loop in the flux–current characteristic (Fig. 4b), and the identical time instants when the flux and current waveforms cross the zero levels (Fig. 4c). Figure 4(d) shows the variation of the state variable x due to changing the terminal current and voltage.
Fig. 4

PSPICE analysis of meminductor from Table 1 excited by harmonic current source. Boundary effects are modeled via Joglekar window

Figure 5 demonstrates another well-known fact from the world of mem-devices: if the frequency of the signal excitation increases, the hysteretic effect in the flux–current characteristic is gradually suppressed.
Fig. 5

PSPICE analysis of meminductor from Table 1 excited by harmonic current source. Boundary effects are modeled via Joglekar window. The memory effect decreases with increasing frequency of excited signal

Figure 6 offers a comparison of meminductor behaviors when the boundary effects are modeled by the Joglekar and the Biolek windows. Meminductors are excited by identical current sources with symmetrical periodical trapezoidal pulse waveforms with MIN/MAX values of −100 μA/+100 μA, with a repeating frequency of 2 Hz, and with 5 ms rise and fall times. Figure 6(a) and (b) show the initial transients whereas Fig. 6(c) and (d) display the steady-state meminductor voltages, currents, and state variables x. Note that whereas the initial transients are almost identical (see Fig. 6a, b), in the steady-state the meminductor modeled by the Joglekar window operates in the regime of x = 1, due to the effect of locking in on the boundary state in which the time derivative of the state variable is zero, and thus it behaves as a conventional linear inductor. The corresponding flux–current characteristic in Fig. 7(a) is a line without any hysteretic behavior. By contrast, the operation of the meminductor with the Biolek window exhibits a steady-state variation of the state variable x (see Fig. 6d), and the hysteretic loop in the flux–current characteristic is evident in Fig. 7(b). Note that the constitutive TIF-charge relation in Fig. 7(d) is not ambiguous because the meminductor now behaves as a more complicated meminductive system.
Fig. 6

PSPICE analysis of meminductors excited by trapezoidal pulse current sources, with boundary effects modeled by Joglekar and Biolek windows. Figures (a) and (b) show initial transients whereas figures (c) and (d) display the steady-state behavior. The meminductor parameters are Lmin = 100 μH, Lmax = 2 mH, Linit = 1 mH, k = 10 A−1 s−1, p = 10

Fig. 7

Steady-state characteristics of the meminductors analyzed in Fig. 6: flux–current characteristics for Joglekar (a) and Biolek (b) windows, TIF-charge characteristics for Joglekar (c) and Biolek (d) windows

4 Conclusions

The methodology described here facilitates effective modeling of meminductive systems of various physical natures in the SPICE-family programs for circuit simulation. An example of the modeling of a current-controlled meminductor whose inductance is changed depending on a state variable, controlled by the meminductor current, is analyzed in detail. The SPICE modeling of flux-controlled meminductive systems can be figured out analogously, following the general model in Fig. 1(b).



Research described in the paper was supported by the Czech Science Foundation under grant No. P102/10/1614, and by the research programmes of BUT Nos MSM0021630503/13 and UD Brno No. MO FVT0000403, Czech Republic.

Open Access

This article is distributed under the terms of the Creative Commons Attribution Noncommercial License which permits any noncommercial use, distribution, and reproduction in any medium, provided the original author(s) and source are credited.


  1. 1.
    Strukov, D. B., Snider, G. S., Stewart, D. R., & Williams, R. S. (2008). The missing memristor found. Nature, 453, 80–83.CrossRefGoogle Scholar
  2. 2.
    Benderli, S., & Wey, T. A. (2009). On SPICE macromodelling of TiO2 memristors. Electronics Letters, 45(7), 377–379.CrossRefGoogle Scholar
  3. 3.
    Biolek, Z., Biolek, D., & Biolková, V. (2009). SPICE model of memristor with nonlinear dopant drift. Radioengineering, 18(2), 210–214.Google Scholar
  4. 4.
    Shin, S., & Kang, S.-M. (2010). Compact models for memristors based on charge–flux constitutive relationships. IEEE Transactions on Computer-Aided Design of Integrated Circuits and Systems, 29(4), 590–598.CrossRefGoogle Scholar
  5. 5.
    Rák, A., & Cserey, G. (2010). Macromodeling of the memristor in SPICE. IEEE Transactions on Computer-Aided Design of Integrated Circuits and Systems, 29(4), 632–636.CrossRefGoogle Scholar
  6. 6.
    Batas, D., & Fiedler, H. (2010). A memristor Spice implementation and a new approach for magnetic flux controlled memristor modeling. IEEE Transactions on Nanotechnology. doi:10.1109/TNANO.2009.2038051.
  7. 7.
    Chen, Y., & Wang, X. (2009). Compact modeling and corner analysis of spintronic memristor. In 2009 IEEE/ACM International Symposium on Nanoscale Architectures, pp. 7–12.Google Scholar
  8. 8.
    Zhang, Y., Zhang, X., & Yu, J. (2009). Approximated SPICE model for memristor. In International conference on communications, circuits and systems, ICCCAS, pp. 928–931.Google Scholar
  9. 9.
    Kavehei, O., Iqbal, A., Kim, Y. S., Eshraghian, K., Al-Sarawi, S. F., & Abbot, D. (2010). The fourth element: Characteristics, modelling, and electromagnetic theory of the memristor. arXiv:1002.3210v1 [cond-mat.mes-hall] 17 Feb 2010.Google Scholar
  10. 10.
    Chua, L. O. (1971). Memristor—The missing circuit element. IEEE Transactions on Circuit Theory, CT-18(5), 507–519.CrossRefGoogle Scholar
  11. 11.
    Chua, L. O. The introductory talk. In Memristor and memristive systems symposium, University of California, Berkeley, 2008.Google Scholar
  12. 12.
    Di Ventra, M., Pershin, Y. V., & Chua, L. O. (2009). Circuit elements with memory: Memristors, memcapacitors and meminductors. Proceedings of the IEEE, 97(10), 1717–1724.CrossRefGoogle Scholar
  13. 13.
    Martinez, J., Di Ventra, M., & Pershin, Y. V. (2009). Solid-state memcapacitor. arXiv:0912.4921v2 [cond-mat.mes-hall] 31 Dec 2009.Google Scholar
  14. 14.
    Krems, M., Pershin, Y.V., & Di Ventra, M. (2010). Ionic memcapacitive effects in nanopores. arXiv:1001.0796v1 [cond-mat.soft] 6 Jan 2010.Google Scholar
  15. 15.
    Di Ventra, M., Pershin, Y. V., & Chua, L. O. (2009). Putting memory into circuit elements: Memristors, memcapacitors, and meminductors. Proceedings of the IEEE, 97(8), 1371–1372.CrossRefGoogle Scholar
  16. 16.
    Biolek, D., Biolek, Z., & Biolková, V. (2009). SPICE modeling of memristive, memcapacitative and meminductive systems. In Proc. int. conf. ECCTD ‘09, Antalya, Turkey, pp. 249–252.Google Scholar
  17. 17.
    Biolek, D., Biolek, Z., & Biolková, V. (2010). SPICE modelling of memcapacitor. Electronics Letters, 46(7), 520–522.CrossRefGoogle Scholar
  18. 18.
    Chua, L. O. (2003). Nonlinear circuit foundations for nanodevices. Part I. The four-Element Torus. Proceedings of the IEEE, 91(11), 1830–1859.CrossRefGoogle Scholar
  19. 19.
    Chua, L. O., & Kang, S. M. (1976). Memristive devices and systems. Proceedings of the IEEE, 64(2), 209–223.CrossRefMathSciNetGoogle Scholar
  20. 20.
    Joglekar, Y. N., & Wolf, S. J. (2009). The elusive memristor: Properties of basic electrical circuits. European Journal of Physics, 30, 661–675.MATHCrossRefGoogle Scholar
  21. 21.
    Pershin, Y. V., & Di Ventra, M. (2010). Memristive circuits simulate memcapacitors and meminductors. Electronics Letters, 46(7), 517–518.CrossRefGoogle Scholar

Copyright information

© The Author(s) 2010

Authors and Affiliations

  • Dalibor Biolek
    • 1
    • 4
  • Zdeněk Biolek
    • 2
  • Viera Biolková
    • 3
  1. 1.Department of MicroelectronicsBrno University of TechnologyBrnoCzech Republic
  2. 2.SŠIEŘ Rožnov p.R.Rožnov p.R.Czech Republic
  3. 3.Department of Radio ElectronicsBrno University of TechnologyBrnoCzech Republic
  4. 4.Department of EEUniversity of Defence BrnoBrnoCzech Republic

Personalised recommendations